注册 登录  
 加关注
   显示下一条  |  关闭
温馨提示!由于新浪微博认证机制调整,您的新浪微博帐号绑定已过期,请重新绑定!立即重新绑定新浪微博》  |  关闭

《电脑之家》

请点击:“日志”浏览电脑知识

 
 
 

日志

 
 

第七课:AS加载和卸载swf文件  

2011-02-02 20:41:16|  分类: AS课堂 |  标签: |举报 |字号 订阅

  下载LOFTER 我的照片书  |
      上一节中,我们已经能创建MC,本节我们将介绍加载外部swf文件的方法。

loadMovie函数及MC的loadMovie()方法:

使用 loadMovie() 函数可以在播放原始 SWF 文件时,将 SWF、JPEG、GIF 或 PNG 文件加载到 Flash Player 中的影片剪辑中。加载的图像或 SWF 文件的左上角与目标影片剪辑的注册点对齐。
格式:loadMovie(“要加载的swf文件或图片“,目标影片剪辑);
要加载的swf文件或图片可以来源于网络,书写格式为:http://....
可以来源于本地硬盘上的文件系统,书写格式为:file:///.......
如果要加载的swf文件或图片与fla文件在同一目录下,则直接写文件名。
目标影片剪辑可以是任何影片剪辑,也可以是主场景,加载后,目标影片剪辑将被替换成加载的文件。
例1:加载一个网络上的swf文件sub.swf到创建的MC中:

this.createEmptyMovieClip("logo_mc", 1);
loadMovie("http://www.jcwcn.com/sub.swf", logo_mc);

例2:加载一个本地的swf文件sub.swf到主舞台:

loadMovie("file:///d:/myflash/sub.swf", this);

例3:加载一个相同目录下的图片picture.jpg到创建的MC中:

this.createEmptyMovieClip("picture_mc", 1);
loadMovie("picture.jpg",picture_mc);

以上是loadMovie函数的写法,而MC的loadMovie()方法也一样,只写法不同,如:this.createEmptyMovieClip("picture_mc", 1);
picture_mc.loadMovie("picture.jpg");

loadMovieNum 函数

在播放原始 SWF 文件时,将 SWF、JPEG、GIF 或 PNG 文件加载到一个级别中。用法跟loadMovie一样,只是它不是指明目标影片剪辑,而加载到一个深度上。比如要加载相同目录下的swf文件myflash.swf到深度为2的级别中:
loadMovieNum(“myflash.swf”,2);
要注意的是,上一节我们介绍了,当深度相同时,新加载的对象会覆盖原来的对象。我们也以用下面一句来加载外部swf文件:
loadMovieNum(“myflash.swf”,this.getNextHighestDepth());
MovieClipLoader类

此类用于实现在 SWF、JPEG、GIF 和 PNG 文件正被加载到影片剪辑中时提供状态信息的侦听器回调。也就是说用这类加载swf文件,可以在加载过程中进行控制,如观察加载进度等。要使用MovieClipLoader类就应首先用构造函数创建一个MovieClipLoader类的实例才能操作其方法,事件,实现加载功能。如:
var mcLoader:MovieClipLoader = new MovieClipLoader();

loadClip方法:该方法的作用和用法与loadMovie()是一样的。如:
this.createEmptyMovieClip("picture_mc", 1);
var mcLoader:MovieClipLoader = new MovieClipLoader();
mcLoader.loadClip("picture.jpg",picture_mc);
上面说到,用本类加载外部swf文件或图片可以在加载过程中加以操作,主要是通过几个事件的调用来实现:onLoadStart事件:在下载的文件的第一个字节写入硬盘后,调用。
格式: onLoadStart = function([target_mc: MovieClip]) {}
其中的target_mc为要加载外部影片的目标MC。

onLoadComplete事件:当加载的文件完全下载时调用。
格式:onLoadComplete = function([target_mc: MovieClip]) {}

onLoadInit事件:当执行加载的剪辑的第一帧上的动作时调用。
在调用此侦听器后,您可以设置属性、使用方法,还可以与加载的影片交互。
格式:onLoadInit = function([target_mc: MovieClip]) {}了解 MovieClipLoader.onLoadComplete和 MovieClipLoader.onLoadInit之间的差异非常重要。onLoadComplete事件在加载 SWF、JPEG、GIF 或 PNG 文件之后但在应用程序初始化之前被调用。此时,无法访问已加载的影片剪辑的方法和属性,因此您无法调用函数、移动到特定帧,等等。在多数情况下,最好改为使用 onLoadInit事件,它在内容已加载并完全初始化后被调用。

onLoadProgress事件:在加载过程中(即在 MovieClipLoader.onLoadStart
和 MovieClipLoader.onLoadComplete
之间时),每当正加载的内容写入硬盘时调用。
格式:onLoadProgress = function([target_mc: MovieClip], loadedBytes: Number, totalBytes: Number) {}
loadedBytes为已经加载的字节数。totalBytes为要加载的swf的总的字节数。如果在测试模式中,您试图对驻留在硬盘上的本地文件使用 onLoadProgress,则它将不能正常工作,这是因为在测试模式中,Flash Player 会将本地文件作为一个整体加载。

onLoadError事件:加载的文件未能加载时调用。出于各种原因,会调用此侦听器;例如服务器关闭、找不到文件或发生安全侵犯。
上述事件的调用方法我给你整成一个公式的模式,直接套用就行了。
MovieClipLoader类事件调用公式:
//首先创建一个MovieClipLoader对象
var mcLoader:MovieClipLoader = new MovieClipLoader();//mcLoader为自已取的名称
//然后创建一个侦听对象
var listener:Object = new Object();//listener为自已取的名称
//调用下列事件之一或多个
listener.onLoadStart = function(target_mc:MovieClip) {}
listener.onLoadComplete = function([target_mc: MovieClip]) {}
listener.onLoadInit = function([target_mc: MovieClip]) {}
listener.onLoadProgress = function([target_mc: MovieClip],
loadedBytes: Number, totalBytes: Number) {}
//MovieClipLoader对象调用侦听对象
mcLoader.addListener(listener);
//MovieClipLoader对象加载外部swf或图片
mcLoader.loadClip(“外部文件地址”,目标影片剪辑);
下面介绍MovieClipLoader类的几个方法

loadClip方法:在播放原始影片时,将 SWF、JPEG、渐进式 JPEG、非动画 GIF 或 PNG 文件加载到 Flash Player 中的影片剪辑中。

addListener(侦听对象)方法:注册一个对象,以便在调用 MovieClipLoader 事件处理函数时接收通知。

getProgress(target: Object)方法:返回正在通过使用 MovieClipLoader.loadClip()
加载的文件的已加载字节数和总字节数;返回一个具有以下两个整数属性的对象:bytesLoaded
和 bytesTotal。

removeListener(侦听对象)方法:删除在调用 MovieClipLoader 事件处理函数时用来接收通知的侦听器。

unloadClip(target: Object)方法:删除通过使用 MovieClipLoader.loadClip() 加载的影片剪辑。
下面通过一个练习来加深理解本节课所介绍的内容,主要运用MovieClipLoader类来加载外部文件加载过程中,用进度条来显示加载进度。本节的练习请保存原文件,待下一节控制时间轴后,将在本练习的基础上,完成一个播放器。
http://www.webjx.com/files/media/1_090124102111.swf
一、新建flash文档,然后在第一层画一个播放器的外形,这个我不作介绍,我画的如下图,你完全可以画得更好看一些。这里要说一说中间的播放屏幕(黑的那块)的大小问题。Flash文档默认的大小是550x400,那么这个播放屏幕也应按这个比例来画,它的大小是文档大小的80%,因此,宽为:550x0.8=440,高为400x0.8=320.将这个播入屏幕水平居中,尽量往上放,将下面多留一些地盘,以后有用。然后用变形工具点中它,将注册点移到左上角,打开属性面板,记录下它的x,y坐标备用。图层上锁。

第七课:AS加载和卸载swf文件 - 自然醒 - 与大家共迎新年到来!
二、新插入一图层,按下图位置放一个静态文本,内容为:“文件地址:”;再放一个输入文本,在属性面板实例名称为:url_txt.新建一按钮元件,标签为:“打开”,属性面板实例名称为:load_btn.将按钮放输入文本右边。

三、新建一MC,取名loading,用矩形工具,禁止笔触,绿色填充,画一个300x5的矩形。然后转换成MC。双击它进新的MC编辑窗口,将矩形条垂直居中,左对齐。打开属性面板,为实例名称取名为:“loadt_mc”.回到loading元件编辑窗口,将矩形元件垂直居中,左对齐。在矩形元件的上面放一静态文本,内容为:“正在加载文件,请稍候…”.在库中右击loading元件,点连接,在“为ActionScript导出“前打钩。在标识标中输入:loading,实际上那里本来就有了,不用输哈,确定。
四、好了,接下来写代码。新建一层,取名为“action”.

打开帧到作面板,输入如下语句:

load_btn.onRelease =function(){

attachMovie("loading","loading_mc",getNextHighestDepth());

loading_mc._x=80;

loading_mc._y=215;

loading_mc.loadt_mc._xscale=0;
var swfurl = url_txt.text;
var type = swfurl.substr(-3,3);
createEmptyMovieClip("swf_mc", 1);
var mcLoader:MovieClipLoader = new MovieClipLoader();
var listener:Object = new Object();
listener.onLoadProgress = function(target:MovieClip, bytesLoaded:Number, bytesTotal:Number):Void {
loading_mc.loadt_mc._xscale=Math.floor((bytesLoaded/bytesTotal)*100);


}
listener.onLoadInit = function(swf_mc){

loading_mc.removeMovieClip();

swf_mc._x=60;

swf_mc._y=8;

if(type == "swf"){

swf_mc._xscale=swf_mc._yscale=80;

} else {

while((swf_mc._width>440)||(swf_mc._height>320)){

swf_mc._xscale -=1;

swf_mc._yscale -=1;

}

}

}
mcLoader.addListener(listener);
mcLoader.loadClip(swfurl,swf_mc);
}
测试影片,在文本框中输入外部swf或图片的地址,点击打开,外部文件将加载到播放窗口中,播放。注意:如果外部文件在网络上,那么就必须用http://.....格式,如果在本地硬盘上,则应输入完整路径,如果与本swf文件在同一个目录中,则只须输入文件名即可。

下面我们来分析下代码
代码分析:

代码全部放在按钮的点击事件中:
load_btn.onRelease =function(){
首先将进度条从库中加载到舞台上,并设置它的位置,使它处于播入屏幕中间,因为现在还没有开始下载,所以设置进度条的长度为0.
attachMovie("loading","loading_mc",getNextHighestDepth());

loading_mc._x=80;

loading_mc._y=215;

loading_mc.loadt_mc._xscale=0;
接下来,声明一个变量swfurl来存放用户在地址文本中输入的外部文件地址。用type来存放地址的最后三个字符,用以判断加载的是swf还是图片。
var swfurl = url_txt.text;
var type = swfurl.substr(-3,3);
创建一个空的MC用来加载外部文件
createEmptyMovieClip("swf_mc", 1);
创建一个MovieClipLoader对象用于加载外部文件,创建一个侦听对象用于调用MovieClipLoader的事件。
var mcLoader:MovieClipLoader = new MovieClipLoader();
var listener:Object = new Object();
调用onLoadProgress事件,即在下载过程中,读取已下载的字节数和总的字节数,并用它们的比值,设置进度条的长度。
listener.onLoadProgress = function(target:MovieClip, bytesLoaded:Number, bytesTotal:Number):Void {
loading_mc.loadt_mc._xscale=Math.floor((bytesLoaded/bytesTotal)*100);

}
调用onLoadInit在加载完成后,删除进度条。并设置加载的文件的位置和大小,使之适应播入屏幕的大小。上面我们记录的播放屏幕的左上角坐标现在有用了,将加载的文件的坐标设为记录的值。文件的大小,首先判定加载的是swf文件还是图片。为什么在判断呢?这是因为加载swf文件后,目标MC的_width和_hight就失灵了,因而就只能用_xscaleswf_,_yscale 来控制,很显然这不科学的,因为加载的swf大小不可能都一样,按比例缩放无法达到精确的尽寸。所以我们只能把要加载的swf文件看成550x400的大小来缩小到80%。而图片则可用宽高属性来设置,所以分开来,整精确一个算一个。按上面存的用户输入的地址的最后三个字符,如果是swf那么就是加载 swf文件了,就用_xscaleswf_,_yscale来控制。如果不是则是加载图片那么就可用宽高属性来判断加载的图片是否大于播放屏幕,如果大了,则调整_xscaleswf_,_yscale属性,使之减小。为什么还是调整_xscaleswf_,_yscale呢?这是为了,使保持宽高比例,以免变形。
listener.onLoadInit = function(swf_mc){

loading_mc.removeMovieClip();

swf_mc._x=60;

swf_mc._y=8;

if(type == "swf"){

swf_mc._xscale=swf_mc._yscale=80;

} else {

while((swf_mc._width>440)||(swf_mc._height>320)){

swf_mc._xscale -=1;

swf_mc._yscale -=1;

}

}

}
最后MovieClipLoader对象侦听侦听对象,加载影片。
mcLoader.addListener(listener);
mcLoader.loadClip(swfurl,swf_mc);

  评论这张
 
阅读(507)| 评论(2)
推荐 转载

历史上的今天

评论

<#--最新日志,群博日志--> <#--推荐日志--> <#--引用记录--> <#--博主推荐--> <#--随机阅读--> <#--首页推荐--> <#--历史上的今天--> <#--被推荐日志--> <#--上一篇,下一篇--> <#-- 热度 --> <#-- 网易新闻广告 --> <#--右边模块结构--> <#--评论模块结构--> <#--引用模块结构--> <#--博主发起的投票-->
 
 
 
 
 
 
 
 
 
 
 
 
 
 

页脚

网易公司版权所有 ©1997-2017